Download Color themes for Everything 1.4

[NotNull]

Yes, no problem.

[Condor]

I don't really understand why in the INI file there are two entries for EXE and INI - I only have one of each.

I have nothing in the location stated in the error.

[NotNull]

I don't really understand why in the INI file there are two entries for EXE and INI - I only have one of each.

I have nothing in the location stated in the error.

You have to change the INI=... entry to the actual location where your Everything.ini is.
That INI file will most likely be in the same folder as your everything.exe


Beside that: there are now two \roaming\ folders in your path ...

Regarding double entries: the ones with a leading semi-colon (;) are commented out. They are examples.

[Condor]

Yes. That is the issue. In Roaming I have no Roaming\everything\everything.ini

Code: Select all

;=== Location of Everything.EXE

;  EXE=N:\Software\Portable Stuff\Everything-1.4.1.1020.x64

;=== Location of Everything.INI

;  INI=N:\Software\Portable Stuff\Everything-1.4.1.1020.x64

;=== Where should EXPORTED themes be saved?

   EXPORT=N:\Software\Portable Stuff\EveryThemes\Exported themes

This is how I configured the INI and I get this error when launching the EveryTheme.cmd

Code: Select all

  EveryTheme.ini misconfiguration.
  Check INI=

Press any key to continue . . .

[NotNull]

Remove the semi-colon in ;INI=...

(same for the ;exe entry)

(In INI files, lines that start wit a ; are comments)

[Condor]

Pfff. Thank you so much. Feel so blonde now.

[NotNull]

You're welcome! Enjoy the themes ...

[Condor]

I tried multiple times to apply one of the themes and I still cannot make it work - application does not restart after applying a theme - it remains in taskbar.

I tried the below solution but still it does not work.

I'm pretty sure I am doing something wrong ... like always

On first sight, it looks like Everything is unable to save it's settings to the INI file.
Everything.ini is in C:\Program Files\Everything\ according to tour Everytheme.ini.
"Normal" users don't have write-access in this folder.

To fix this:

• Enable Store settings and data in %APPDATA%\Everything (Menu:Tools > Options > General)
• In you Everytheme.ini, replace the line INI=C:\Program Files\Everything\Everything.ini with:

  Code: Select all

  INI=%APPDATA%\Everything\Everything.ini

After these modifications, what happens if you double-click one of the .everytheme files?


Note:
If you enable ]Store settings and data in %APPDATA%\Everything, there will still be a (stripped down) Everything,ini in your Program files\Everything folder. This is by design.

Current INI looks like this:

Code: Select all

;=== Location of Everything.EXE

  EXE=N:\Software\Portable Stuff\Everything-1.4.1.1020.x64

;=== Location of Everything.INI

  INI=%APPDATA%\Everything\Everything.ini
  INI=N:\Software\Portable Stuff\Everything-1.4.1.1020.x64

;=== Where should EXPORTED themes be saved?

   EXPORT=N:\Software\Portable Stuff\EveryThemes\Exported themes

Also leaving any one of the INI location lines does not change anything.

[ajaxStardust]

This is nice!
I'm just getting starting w/ Everything. It is, indeed, every-thing!

I was going to post a new thread, but this will do.

I just discovered that I can create my own Filters. It would be really fantastic and useful if you (voidtools) setup a repo for us to share Custom Filters as well. Just an idea.

how cool is that?

[NotNull]

application does not restart after applying a theme
[...]
Current INI looks like this:

Code: Select all

;=== Location of Everything.EXE

  EXE=N:\Software\Portable Stuff\Everything-1.4.1.1020.x64

;=== Location of Everything.INI

  INI=%APPDATA%\Everything\Everything.ini
  INI=N:\Software\Portable Stuff\Everything-1.4.1.1020.x64

;=== Where should EXPORTED themes be saved?

   EXPORT=N:\Software\Portable Stuff\EveryThemes\Exported themes

Your EXE=N:\Software\Portable Stuff\Everything-1.4.1.1020.x64 entry is missing is missing the location of everything.exe itself.
Try it with the following:

Code: Select all

  EXE=N:\Software\Portable Stuff\Everything-1.4.1.1020.x64\everything.exe

[gmknowles]

Does not seem to work running as portable app. Version 1.4.1.1022 (x64)

[NotNull]

Are you running Everything as administrator (elevated)?

[TheWacoKid]

Had major problems getting this so work so kept getting errors for Reg Add so altered the cmd and removed the usage of the ini file to make it easier to troubleshoot. Config section is at top of cmd. This also makes the context menu work under Win11 22H2 (except restarting everything after applying the new ini, but couldn't be bothered with fixing that)

Code: Select all

@echo off

setlocal
pushd "%~dp0"

::---------------------------------------------
::                Config Section
::---------------------------------------------
::;=== Location of Everything.EXE
::;  EXE=c:\tools\everything\everything.exe
   set EXE=C:\Program Files\Everything\Everything.exe
::
::;=== Location of Everything.INI
::;  INI=c:\tools\everything\everything.ini
   set INI=%APPDATA%\Everything\Everything.ini

::;=== Where should EXPORTED themes be saved?
   set EXPORT=%APPDATA%\Everything\Themes
::
::;=== Icon to use in File Explorer (etc.)
::;    If not defined: use Everything.exe icon
::;
::;	Some examples:
::;	ICON=c:\path to\My Favorite.ico
::;	ICON=%SystemRoot%\system32\compstui.dll,-64040
   set ICON=C:\Program Files\Everything\Everything.exe
::;=== Location of EveryTheme.cmd
   set CMDPATH=%APPDATA%\Everything\EveryTheme 1.2\EveryTheme.cmd
::---------------------------------------------
::               End Config Section
::---------------------------------------------
::
::	INIT
::---------------------------------------------
::

::	Read INI file
::	For /f "eol=; delims=" %%x in (EveryTheme.ini) do call set %%x

::	color 80

::-------------------------------------------
::	Check INI entries
::-------------------------------------------
	If not exist "%EXE%" set ERROR=Check EXE=%EXE%

	If not exist "%INI%" set ERROR=Check INI=%INI%

	If not exist "%EXPORT%\" set ERROR=Check EXPORT=%EXPORT%
	
	If not DEFINED ICON set ICON=%EXE%
	For /f "delims=," %%x in ("%ICON%") do if not exist "%%x" set ERROR=Check ICON=%ICON%

	If Defined ERROR (
		color 0C
		echo.
		echo.  EveryTheme.ini misconfiguration.
		echo.  %ERROR%
		echo.
		echo.  
		echo.  ^( INI: %~dp0Everytheme.ini ^)
		echo.
		echo.
		pause
		goto :EOF
	)

	

::---------------------------------------------
::
::	ACTION!
::---------------------------------------------
::	

::	Check parameters. If .everytheme file: import it.
::	If other parameter: warning + quit

	If [%1] neq [] (	:: There are parameters
		If /i [%~x1] equ [.everytheme] (
			findstr /i /v /R "_bold= _color= _font= ^[ ]*;" %1 || goto :IMPORT
		)	
		:: If we end up here: Invalid filecontent or invalid fileextension
		echo.
		echo.	Not a valid Everything theme file: %1.
		echo.
		pause
	goto :EOF
	)


::	We're here because there was no parm given. Show menu.

::	If not registered, goto :REGISTER routine
	set REGISTERED=NOT
	REG.exe QUERY "HKCU\Software\Classes\.Everytheme\Shell\Import\Command" >nul 2>nul && set REGISTERED=already

	echo.---------------------------------------------------------
	echo.	Shell integration %REGISTERED% installed !
	echo.---------------------------------------------------------
	echo.	
	echo.	[E] - Export current Everyting color scheme
	echo.	
	echo.	[I] - (re-) Install shell integration
	echo.	[R] - Remove shell integration
	echo.	[Q] - Quit
	echo.	
	echo.
	echo.	      When the shell integration is installed,	
	echo.	      you can double-click a .Everytheme file 
	echo.	      to import that color scheme.
	echo.	      Everything will be automatically stopped and
	echo.	      restarted to activate this new color scheme.
	echo.	
	echo.
	CHOICE.exe /C EIRQ /M "Select E, I, R or Q"

	Goto Choice%ERRORLEVEL%
	
::	End of program


::---------------------------------------------
::
::	SUBROUTINES
::---------------------------------------------
::


::------------------------------------------------------
	:CHOICE1	:: Export current Everyting color scheme
::------------------------------------------------------

::	Export the current color settings to a file

	:NAMELOOP
	::	Ask for filename
		Set /p ThemeName="Name for current color settings: "
		If exist "%EXPORT%\%ThemeName%.everytheme" (
			echo.
			echo.
			CHOICE.exe /M "Theme """%ThemeName%""" already exists. Overwrite?"
			If ERRORLEVEL 2 goto :NAMELOOP
		)

	::	export themesettings
		findstr /i "_color= _bold= _font=" "%INI%" > "%EXPORT%\%ThemeName%.everytheme"
		echo.
		echo.   Exported theme can be found here:
		echo.   "%EXPORT%\%ThemeName%.everytheme"
		echo.
		pause
goto :EOF	




::------------------------------------------------------
	:CHOICE2	:: Install shell integration
::------------------------------------------------------

::	Register .Everytheme file extension

	(
	REG.exe ADD "HKCU\Software\Classes\.Everytheme" /ve /d "Everything Theme" -f  
	REG.exe ADD "HKCU\Software\Classes\.Everytheme\DefaultIcon" /ve /d "%ICON%" -f
	REG.exe ADD "HKCU\Software\Classes\.Everytheme\Shell" /ve /d "Import EveryTheme" -f
	REG.exe ADD "HKCU\Software\Classes\.Everytheme\Shell\Import\Command" /ve /d "\"%~f0\" \"%%1"\" -f
	) >nul
	echo. Shell Integration Installed
	pause
goto :EOF


::------------------------------------------------------
	:CHOICE3	:: Unregister .Everytheme file extension
::------------------------------------------------------

	REG.exe DELETE "HKCU\Software\Classes\.Everytheme" /f
	echo. Removed Shell Integration
	pause

goto :EOF


::------------------------------------------------------
	:CHOICE4	:: Quit
::------------------------------------------------------

goto :EOF



::------------------------------------------------------
	:IMPORT		:: Import the .everytheme color scheme
::------------------------------------------------------


::	Stop running Everything
	start /wait "" "%EXE%" -quit

::	Load INI entries
	Copy /b "%INI%" + %1 "%INI%" >nul

	
::	Start Everything
	start "" "%EXE%"

goto :EOF

[MMZ_Thumper]

Hello everyone!

I found out about Everything after watching a YouTube video about the 55 Most Useful Free Software where Everything was mentioned. And no, this is in no way a plug or endorsement for the YouTube channel. I'm simply citing my sources to give credit where it's due. I HOPE I DON'T GET IN TROUBLE FOR THAT

But I digress. I've got Everything up and running but I've run into a bit of an issue with trying to get Everytheme up and running. I unzipped the theme files and the license into one folder and unzipped the app into its own folder and copied the main folder to the Everything folder located at C:\Program Files\Everything\Everything Themes. The issue that I'm having is modifying the .ini file to my circumstance. I'm not exactly sure what that means??? And for finding %APPDATA% I can't find it anywhere!

I'm certain that there is already a thread located somewhere that has the answers that I'm looking for but seeing that I've only registered not but an hour ago, I have no idea where anything is, nor do I even know how to search for anything yet. So, for that, I give my deepest apologies and respectfully ask for forgiveness! I really like this app and look forward to using it in the future! Any and all help will be greatly appreciated!!!!!

If I need to move this to a different thread plz let me know where it is, and I will do so as quickly as possible.

Oh! I almost forgot!
Software Information

Edition: Windows 11 Pro
Version: 22H2
Installed on: ‎3/‎21/‎2023
OS build: 22624.1465
Experience: Windows Feature Experience Pack 1000.22640.1000.0

[PadMan]

The following script was modified for Windows 11 and it works for portable of Everything
It should work

• Create file name like EveryThemePortable.cmd and place the following code next to Everything.exe (The .ini file from first post doesn't work )
• Create a new folder called Themes next to Everything.exe and place preferred themes

Code: Select all

@ECHO OFF

SETLOCAL
PUSHD "%~dp0"

:: Modified for Windows 11 (2023-09-24 by PadMan)

::---------------------------------------------
::                Config Section
::---------------------------------------------
::;=== Location of Everything.EXE
::;  EXE=c:\tools\everything\everything.exe
   ::SET EXE=C:\Program Files\Everything\Everything.exe
   SET EXE=Everything.exe
::
::;=== Location of Everything.INI
::;  INI=c:\tools\everything\everything.ini
   ::SET INI=%APPDATA%\Everything\Everything.ini
   SET INI=Everything.ini

::;=== Where should EXPORTED themes be saved?
   ::SET EXPORT=%APPDATA%\Everything\Themes
   SET EXPORT=Themes
::
::;=== Icon to use in File Explorer (etc.)
::;    If not defined: use Everything.exe icon
::;
::;	Some examples:
::;	ICON=c:\path to\My Favorite.ico
::;	ICON=%SystemRoot%\system32\compstui.dll,-64040
   ::SET ICON=C:\Program Files\Everything\Everything.exe
   SET ICON=Everything.exe
::;=== Location of EveryTheme.cmd
   ::SET CMDPATH=%APPDATA%\Everything\EveryTheme 1.2\EveryTheme.cmd
   ::SET CMDPATH=EveryTheme.cmd
   SET CMDPATH=%~nx0

::
::---------------------------------------------
::               End Config Section
::---------------------------------------------
::
::	INIT
::---------------------------------------------
::

:: BEGIN SET REG PATH FOR Everything
SET REG1=HKCU\Software\Classes\.everytheme\Shell\Import\Command
SET REG2=HKCU\Software\Classes\EveryTheme.2023
SET REG3=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.everytheme
:: END SET REG PATH FOR Everything

::	Read INI file
::	For /f "eol=; delims=" %%x in (EveryTheme.ini) do call set %%x

::	color 80

::-------------------------------------------
::	Check INI entries
::-------------------------------------------
	If not EXIST "%EXE%" SET ERROR=Check EXE=%EXE%

	If not EXIST "%INI%" seSETt ERROR=Check INI=%INI%

	If not EXIST "%EXPORT%\" SET ERROR=Check EXPORT=%EXPORT%
	
	If not DEFINED ICON SET ICON=%EXE%
	For /f "delims=," %%x in ("%ICON%") do if not EXIST "%%x" set ERROR=Check ICON=%ICON%

	If Defined ERROR (
		color 0C
		ECHO.
		ECHO.  EveryTheme.ini misconfiguration.
		ECHO.  %ERROR%
		ECHO.
		ECHO.  
		ECHO.  ^( INI: %~dp0Everytheme.ini ^)
		ECHO.
		ECHO.
		PAUSE
		goto :EOF
	)

	

::---------------------------------------------
::
::	ACTION!
::---------------------------------------------
::	

::	Check parameters. If .everytheme file: import it.
::	If other parameter: warning + quit

	If [%1] neq [] (	:: There are parameters
		If /i [%~x1] equ [.everytheme] (
			FINDSTR /i /v /R "_bold= _color= _font= ^[ ]*;" %1 || goto :IMPORT
		)	
		:: If we end up here: Invalid filecontent or invalid fileextension
		ECHO.
		ECHO.	Not a valid Everything theme file: %1.
		ECHO.
		PAUSE
	GOTO :EOF
	)


::	We're here because there was no parm given. Show menu.

::	If not registered, goto :REGISTER routine
	set REGISTERED=NOT
	REG.exe QUERY "%REG1%\Shell\Import\Command" >nul 2>nul && set REGISTERED=already

	ECHO.---------------------------------------------------------
	ECHO.	Shell integration %REGISTERED% installed !
	ECHO.---------------------------------------------------------
	ECHO.	
	ECHO.	[E] - Export current Everyting color scheme
	ECHO.	
	ECHO.	[I] - (re-) Install shell integration
	ECHO.	[R] - Remove shell integration
	ECHO.	[Q] - Quit
	ECHO.	
	ECHO.
	ECHO.	      When the shell integration is installed,	
	ECHO.	      you can double-click a .Everytheme file 
	ECHO.	      to import that color scheme.
	ECHO.	      Everything will be automatically stopped and
	ECHO.	      restarted to activate this new color scheme.
	ECHO.	
	ECHO.
	CHOICE.exe /C EIRQ /M "Select E, I, R or Q"

	GOTO Choice%ERRORLEVEL%
	
::	End of program


::---------------------------------------------
::
::	SUBROUTINES
::---------------------------------------------
::


::------------------------------------------------------
	:CHOICE1	:: Export current Everyting color scheme
::------------------------------------------------------

::	Export the current color settings to a file

	:NAMELOOP
	::	Ask for filename
		SET /p ThemeName="Name for current color settings: "
		If EXIST "%EXPORT%\%ThemeName%.everytheme" (
			ECHO.
			ECHO.
			CHOICE.exe /M "Theme """%ThemeName%""" already exist. Overwrite?"
			If ERRORLEVEL 2 goto :NAMELOOP
		)

	::	export themesettings
		FINDSTR /i "_color= _bold= _font=" "%INI%" > "%EXPORT%\%ThemeName%.everytheme"
		ECHO.
		ECHO.   Exported theme can be found here:
		ECHO.   "%EXPORT%\%ThemeName%.everytheme"
		ECHO.
		PAUSE
GOTO :EOF	




::------------------------------------------------------
	:CHOICE2	:: Install shell integration
::------------------------------------------------------

::	Register .Everytheme file extension

	(
	REG.exe ADD "%REG1%\OpenWithProgids" /t REG_SZ /d "" /v "EveryTheme.2023" /f
	REG.exe ADD "%REG2%" /ve /d "Everything Theme" -f
	REG.exe ADD "%REG2%\DefaultIcon" /ve /d "\"%~dp0%ICON%"\" /f
	REG.exe ADD "%REG2%\Shell" /ve /d "Import EveryTheme for Everything" -f
	REG.exe ADD "%REG2%\Shell\Import" /t REG_SZ /v "FriendlyAppName" /d "EveryTheme Importer for Everything" /f
	REG.exe ADD "%REG2%\Shell\Import\Command" /ve /d "\"%~f0\" \"%%1"\" -f
	) >NUL
	ECHO.
	ECHO. Shell Integration Installed
	ECHO.
	PAUSE
goto :EOF


::------------------------------------------------------
	:CHOICE3	:: Unregister .Everytheme file extension
::------------------------------------------------------

	REG.exe DELETE "%REG1%" /f >NUL 2>NUL
	REG.exe DELETE "%REG2%" /f >NUL 2>NUL
	REG.exe DELETE "%REG3%" /f >NUL 2>NUL
	ECHO.
	ECHO. Removed Shell Integration
	ECHO.
	PAUSE

goto :EOF


::------------------------------------------------------
	:CHOICE4	:: Quit
::------------------------------------------------------

goto :EOF



::------------------------------------------------------
	:IMPORT		:: Import the .everytheme color scheme
::------------------------------------------------------

::	Stop running Everything
	START /wait "" "%EXE%" -quit
	TASKKILL /F /IM Everything.exe /T >NUL

::	Load INI entries
	COPY /b "%INI%" + %1 "%INI%" >NUL
	
::	Start Everything
	START "" "%EXE%" >NUL

goto :EOF

After created file and installed shell support, go to Themes and double click on your preferred theme(.everytheme)

Have fun

[jilmaxr]

Hello,

First of all, this is god's work. Thank you so much. I have been hoping for a dark theme for ages.

I have followed the instructions until the time I open an .everyttheme file I get the error

"Not a valid Everything theme file "C:\Path""

Where path is the URL to my theme file that I downloaded

Screenshot 2024-04-19 090613.png (13.54 KiB) Viewed 6431 times

[horst.epp]

First of all, this is god's work. Thank you so much. I have been hoping for a dark theme for ages.

Switch to Everything 1.5 and you have a native Dark theme
and also a lot more functions.