When I make these drives writable again, clearing the ReadOnly attributes from the Volume and Disk, and then do make changes to files... Everything does not register these changes. Even on NTFS volumes.
It would seem that Everything pauses monitoring for changes, either when it detects that a device is ReadOnly, or at some point in DISKPART's unmounting remounting process.
The only solution is to rebuilt the entire index, especially since NTFS volumes do not have a "Rescan Now" option.
disk-readonly.cmd
Code: Select all
@rem disk-readonly.cmd script by Raccoon 2016
@rem DISKPART: ATTR DISK SET/CLEAR READONLY
@echo off
fltmc >nul 2>&1 && ( goto admin ) || ( goto noadmin )
:noadmin
echo This script must be 'Run As Administrator'.
echo Exiting...
echo.
pause
goto end
:admin
echo Setting drive %~d0 to READONLY...
echo ^>^> ARE YOU SURE? ^<^<
echo.
pause
( echo sele vol %~d0
echo list vol
echo attr vol set readonly
echo deta vol
echo attr disk set readonly
echo deta disk ) | diskpart
echo.
echo.
if %ERRORLEVEL% == 0 (
echo SUCCESS! Drive %~d0 should now be READONLY.
) else (
echo Failure setting %~d0 to READONLY.
)
echo.
pause
:endCode: Select all
@rem disk-writeable.cmd script by Raccoon 2016
@rem DISKPART: ATTR DISK SET/CLEAR READONLY
@echo off
fltmc >nul 2>&1 && ( goto admin ) || ( goto noadmin )
:noadmin
echo This script must be 'Run As Administrator'.
echo Exiting...
echo.
pause
goto end
:admin
echo Setting drive %~d0 to WRITEABLE...
echo ^>^> ARE YOU SURE? ^<^<
echo.
pause
( echo sele vol %~d0
echo list vol
echo attr disk clear readonly
echo deta disk
echo attr vol clear readonly
echo deta vol ) | diskpart
echo.
echo.
if %ERRORLEVEL% == 0 (
echo SUCCESS! Drive %~d0 should now be WRITEABLE.
) else (
echo Failure setting %~d0 to WRITEABLE.
)
echo.
pause
:end